Scripter wanted: Low Pay, Eternal Glory....

[Rufferta]

Nevermind - I was wanting to have the "Continent Locator" script updated to include Sharp, and I see it has been. Unfortunately the updated script now does not include Caledon. I am thinking that the script might be better named "Where Am I?" and forget worrying about whether or not a place is on a Continent and just include places a newcomer is likely to land. Nevertheless, a great and useful script and I am grateful to those who had the skill to make it.

Now, perhaps, a script to update scripts so that folks like me always have the newest one?

// Script by Dale Innis, January 2011.  You may do whatever you like with this script, without limitation.
 
// Updated June 2011, June 2013, March 2014, December 2015 and February 2021 by Braclo Eber.
// Please see changelogs below for details. It was getting too long to keep at the start of the script.
 
// NOTE: Due to how close some regions are to the private continents, some might indicate they are part of the continent due to how the script works.
// -----
 
// Each set of five list elements represents a grid-aligned rectangle, in the form xmin,xmax,ymin,ymax,name.
// The code returns the FIRST one that it finds, so its okay if the rectangles overlap, as long as you put
// the right one first.
 
list map = [
 270592.0,276712.0,249088.0,253952.0,"Bellisseria East",
 261888.0,272128.0,240896.0,250112.0,"Bellisseria",
 296704.0,301824.0,252928.0,256512.0,"Sharp",
 257024.0,266240.0,229888.0,240640.0,"Jeogeot",
 251392.0,254464.0,256000.0,257280.0,"Bay City",
 254720.0,265984.0,250368.0,259072.0,"Sansara",
 253696.0,259840.0,259328.0,265472.0,"Heterocera",
 281344.0,290560.0,257280.0,268288.0,"Satori",
 290048.0,290816.0,268288.0,270080.0,"Western Blake Sea",
 290816.0,295424.0,266496.0,272128.0,"Blake Sea",
 286720.0,290048.0,268288.0,269056.0,"Nautilus City",
 283136.0,291072.0,268288.0,276992.0,"Nautilus",
 281600.0,296448.0,276992.0,281856.0,"Corsica",
 291840.0,295936.0,284672.0,289536.0,"Gaeta I",
 296960.0,304640.0,276736.0,281600.0,"Gaeta V",
 460032.0,466432.0,301824.0,307456.0,"Zindra",
// List of private continents.
 117504.0,123136.0,   435200.0,440320.0,"Eden",
 250112.0,254720.0,   245248.0,248576.0,"Estate",
 282624.0,284160.0,   268288.0,270080.0,"FairChang",
// and then for places outside the bounds of mainland continents, some random names...
      0.0,250000.0,     0.0,999999.0,"the Western Ocean",  
 250000.0,265000.0,     0.0,999999.0,"the West",        
 265000.0,280000.0,     0.0,999999.0,"the Center Longitudes",         
 280000.0,310000.0,     0.0,999999.0,"the East",          
 310000.0,450000.0,     0.0,999999.0,"the Gap Longitudes",           
 450000.0,500000.0,     0.0,999999.0,"the Zindra Longitudes",            
 500000.0,999999.0,     0.0,999999.0,"the Far East"
];
 
string get_continent_name(vector gc) {
    integer count = llGetListLength(map);
    integer i;
    for (i=0;i<count;i+=5) {
        if ((gc.x>=llList2Float( map,i )) &&
            (gc.x<=llList2Float( map,i+1 )) &&        
            (gc.y>=llList2Float( map,i+2 )) &&                                
            (gc.y<=llList2Float( map,i+3 )) ) return llList2String( map,i+4 );
    }
    return "";
}
 
say_location() {
    vector gc = llGetRegionCorner()+llGetPos();
    llOwnerSay("Coordinates: "+(string)gc.x+","+(string)gc.y);
    string s = get_continent_name(gc);
    if (s!="") {
        llOwnerSay("You are in "+s);
    } else {
        llOwnerSay("You are not in any known area.");
    }  
}
 
default
{
 
    changed(integer change) {
        if (change & CHANGED_TELEPORT) say_location();
    }
 
    touch_start(integer total_number) {
         say_location();
    }
}

// Changelog
// Created January 2011 by Dale Innis
 
// Updated June 2011 by Braclo Eber. 
// Some border sims of continents were missing from the detector.
// Changed some figures to be more accurate. (Nautilus Continent & Bay City Extension)
// Changed the order of the continents to reflect the changes.
// Included Nautilus City.
 
// Updated June 2013 by Braclo Eber.
// Updated coordinates for missing border regions on continents.
 
// Updated March 2014 by Braclo Eber.
// Small fix for Western Blake Sea,Blake Sea,Nautilus and Nautilus City. 
 
// Updated December 2015 by Braclo Eber.
// Added 11 private continents that currently qualify as continents as per http://slgi.wikia.com/wiki/List_Of_Continents
 
// Updated February 2021 by Braclo Eber
// Added Bellisseria - Split it due to the shape of the continent.
// Added Sharp - also known as the old Teen grid.
// Updated Eden and FairChang - Continents Moved
// Removed Winterfell, Mar Lesbiana, Crossing Sands and Shopping - These continents does not exist anymore.
// Removed Caledon, Wild West, Freedom and Uhre - These are not classified as continents anymore due to the requirements of at least 30 sims as per https://wiki.secondlife.com/wiki/List_Of_Continents

Edited April 13, 2021 by Rufferta
I have a talent for overlooking the obvious.

[Quistess Alpha]

Huh neat script.

Do you still have the 2015 version? If you do, it would be easy to add back in Caledon, Wild West, Freedom and Uhre by copy-pasting the relevant lines.

Edited April 15, 2021 by Quistessa

[VirtualKitten]

On 4/13/2021 at 10:56 AM, Rufferta said:

Now, perhaps, a script to update scripts so that folks like me always have the newest one?

Do you mean you wanted an updated map list of new places ? You can add these yourself .

Your touch on your script gives you the location your  when you touch it where you are located  in same format  ie  place a line above or below note the commas and add the location in first three separated by coma's and in quotes the name just the same :

list map = [
 270592.0,276712.0,249088.0,253952.0,"Bellisseria East",

[Quistess Alpha]

It's not /hard/ to do, just confusing, especially with the fact that for overlapping squares, order matters.

if it were me I would have at least ordered the numbers x1 y1 x2 y2 for lower left and upper right corners, which would make it easier for me personally to use, but it's not my project and not a script I see myself using so not going to bother.