Help: AllowDropInventory() Timer

[Christopher Organiser]

How would I set llSetTimerEvent() so when someone clicks on an object, it will llAllowDropInventory(TRUE) for 120 seconds and automatically switch it back to llAllowInventoryDrop(FALSE)?  Thank you in advance! :)

[Darkie Minotaur]

You simply put llSetTimerEvent(120.0) inside the touch event - and then in the timer event, you switch the timer off by setting llSetTimerEvent(0)  and the llAllowInventoryDrop(FALSE) as well

[Ela Talaj]

Try something like this:

integer lock;
default
{
  ...
  ...

  touch_start(integer total_num)
  {
    if(!lock)
      {
      lock = TRUE;
      llAllowInventoryDrop(TRUE);
      llSetTimerEvent(120.0);
      }
  }

  timer()
  {
    llSetTimerEvent(0.0);
    lock = FALSE;
    llAllowInventoryDrop(FALSE);
  }          
}

 

[Kaluura Boa]

2 answers already while I was typing? I am getting old.. Well, at least, Ela's post made me think about a lock.

 

integer TimeLeft;

key Dropper;


default

{

    state_entry()

    {

        llSetText("Click to drop your object", <1.0, 1.0, 1.0>, 1.0);

    }

    

    touch_end(integer num)

    {

        if (Dropper) { return; } // Already busy.

        //

        llSetText("", <1.0, 1.0, 1.0>, 1.0);

        Dropper = llDetectedKey(0);

        llRegionSayTo(Dropper, 0, "/me -- You have 2 minutes to drop.");

        llAllowInventoryDrop(TRUE);

        TimeLeft = 90; // + 30 of timer = 120

        llSetTimerEvent(30.0); // No stress...

    }

    

    timer()

    {

        if (TimeLeft > 0)

        {

            llRegionSayTo(Dropper, 0, "/me -- Time left: " + (string)TimeLeft + " sec.");

            if (TimeLeft > 30)

            {

                TimeLeft -= 30;

            }

            else

            {

                TimeLeft -= 10;

                llSetTimerEvent(10.0); // Now, you can stress!

            }

        }

        else

        {

            llSetTimerEvent(0.0); 

            llAllowInventoryDrop(FALSE);

            llRegionSayTo(Dropper, 0, "/me -- Time out!");

            Dropper = "";

            llSetText("Click to drop your object", <1.0, 1.0, 1.0>, 1.0);

        }

    }

    

    changed(integer change)

    {

        if (change & CHANGED_INVENTORY)

        {

            if (Dropper) // is a valid key

            {

                llSetTimerEvent(0.0); 

                llAllowInventoryDrop(FALSE);

                llRegionSayTo(Dropper, 0, "/me -- Thank you.");

                llSetText("Click to drop your object", <1.0, 1.0, 1.0>, 1.0);

            }

        }

    }

}

Compiled and tested in-world.

 

[Christopher Organiser]

Thank you for all the support!  I got it to work as planned!