(edge & (CONTROL_LBUTTON)) triggers twice

[marcin1995 Sharple]

Hello!

I am making a script, that bursts particles for a short amount of time and so far its working good.

My problem is just, that it triggers the particle when i beginn to press LButton and when i release it, which means twice per full click.

Can someone help me to avoid this?

 

this is the control part:

    control(key owner,integer level, integer edge)
    {

        if (edge & (CONTROL_LBUTTON))
        {
            particle();
        llSetTimerEvent(0.5);

        }

    }
    timer()
    {
        particleTriggered = 0;
        stopParticle();
    }

 

I already tried, to work with integer level instead of edge and i can't make it look good like this

[KT Kingsley]

It's reacting to both the edge caused by pressing the button and to the edge caused by releasing the button. To have it react to just the button press, check the level – whether the button is pressed – as well as the edge:

if (edge & (CONTROL_LBUTTON) && level & (CONTROL_LBUTTON))

Edited April 2, 2020 by KT Kingsley

[marcin1995 Sharple]

That's it, thank you so much!!! ♥

[Wulfie Reanimator]

I like to rename "level" and "edge" to "held" and "click" to be more intuitive.

One press of the mouse results in two "clicks." One when you press it initially, and one when you release the button.

The button is "held" during the first click and until the second click happens. (It's not held anymore during the second click.)

if (CONTROL_ML_LBUTTON & click & held)   // click
if (CONTROL_ML_LBUTTON & held)           // held
if (CONTROL_ML_LBUTTON & click & ~held)  // release
if (CONTROL_ML_LBUTTON & ~click & ~held) // not used

 

Edited April 2, 2020 by Wulfie Reanimator

[KT Kingsley]

32 minutes ago, Wulfie Reanimator said:

 

if (CONTROL_ML_LBUTTON & click & held)   // click
if (CONTROL_ML_LBUTTON & held)           // held
if (CONTROL_ML_LBUTTON & click & ~held)  // release
if (CONTROL_ML_LBUTTON & ~click & ~held) // not used

 

Aren't things going to get a bit wonky if you try to combine conditions like that? For example, if (CONTROL_ML_LBUTTON & click & held) will return TRUE if either click or held are TRUE, as it takes only a single bit to be set for the result to be TRUE.

Using that example, don't you need an expression like if ((CONTROL_LBUTTON & click) && (CONTROL_LBUTTON & held)) or if (CONTROL_LBUTTON & (click | held)) == (click | held))?

Edited April 2, 2020 by KT Kingsley

[Wulfie Reanimator]

1 hour ago, KT Kingsley said:

Aren't things going to get a bit wonky if you try to combine conditions like that? For example, if (CONTROL_ML_LBUTTON & click & held) will return TRUE if either click or held are TRUE, as it takes only a single bit to be set for the result to be TRUE.

Using that example, don't you need an expression like if ((CONTROL_LBUTTON & click) && (CONTROL_LBUTTON & held)) or if (CONTROL_LBUTTON & (click | held)) == (click | held))?

"CONTROL_ML_LBUTTON & click & held" will not return true if either condition is true. You're confusing & with |. Wear this:

default
{
    control(key id, integer held, integer click)
    {
        string text = "held " + (string)held + " click " + (string)click + "\n";

        if (CONTROL_LBUTTON & click & held)
        {
            text += "click";
        }
        if (CONTROL_LBUTTON & held)
        {
            text += "held";
        }
        if (CONTROL_LBUTTON & click & ~held)
        {
            text += "release";
        }
        if (CONTROL_LBUTTON & ~click & ~held)
        {
            text += "off"; // Won't work with a single button.
        }

        llSetText(text, <1,1,1>, 1);
    }

    changed(integer change)
    {
        if (change & CHANGED_OWNER) llResetScript();
    }

    state_entry()
    {
        if (llGetAttached()) llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    }

    attach(key id)
    {
        if (id) llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    }

    run_time_permissions(integer perm)
    {
        if (perm)
        {
            llTakeControls(CONTROL_LBUTTON, TRUE, TRUE);
        }
    }
}

To explain just a little bit, "value & value" has a non-zero result only when those values have matching bits, eg.
1000 & 0001 = 0000
1110 & 0111 = 0110
1111 & 0000 = 0000

Edited April 2, 2020 by Wulfie Reanimator

[KT Kingsley]

Yeah, sorry, you're right. I was confusing this with the situation with permissions and changes, which is completely different.

Edited April 2, 2020 by KT Kingsley