Poses and facial expressions problem.

[Chiwana Vidor]

I've been creating poses for a while, and decided to add facial expressions to a funny couples pose I just created, but I stumbled upon a problem.

I set the pose to priority 4, looped it, added the desidered facial expression from the drop down menu, and uploaded it.

The issue now is that the facial expression does not show up at all, or just shows up and fades within a few seconds. Can anybody explain me what to do to make the facial expression appear as wanted and actually stick to the face during the entire duration of the pose (ie, til the av's jump off the poseballs)?

[robin Meridoc]

I'm not sure what you mean by "added the desidered facial expression from the drop down menu, and uploaded it. ".   But beyond that I did have a similar problem to what you're describing.  I"ll try to describe it and let you decide if it fits your situation or not.

I wrote a script add menu driven expressions to a 'smiler'.  The symptoms of my problem were similar to those you describe.  Sometimes the expression I selected would show up, sometimes not, and sometimes it would do surprising things involving waving of hands or something like that.  

It took two things to solve the problem.  I had to add commands in the script to suspend my AO at the start of the expression, and then turn it back on.  And I had to add a delay, make the script sleep for a second or two between turning the AO off and back on. 

The expressoins I'm referring to here are more than just facial. For example 'repulse' involves the whole body, not just the face.  Many are like that.

robin

[Catwise Yoshikawa]

The expression in the upload pose just works first seconds of you animation.
You have to use a script to have that expression all the time. Guess you could find it on the wiki ;-)

 

Edit: I was searching today for the script in old forum and found it here http://forums-archive.secondlife.com/54/10/301343/1.html

post by Innula Zenovka:

list gAnimations = ["express_toothsmile","express_tongue_out" ];


  restartAnimations()

  {

  	integer i ;

  	integer max = llGetListLength(gAnimations) ;

  	string ani ;

  	for (i=0;i<max;i++)

  	{

  		ani = llList2String(gAnimations, i) ;

  		llStopAnimation(ani) ;

  		llStartAnimation(ani) ;

  	}

  }

  string sitAnimation="";


  // if sitAnimation is left blank

  // the script will grab the first animation in the container.

  // if a value is set, it will use that instead.




  default {

  	on_rez(integer start_param) {

  		llResetScript();

  	} 


  	state_entry() {

  		llSetText("Sit to Pose", <0.0,1.0,0.0>, 1);

  		llSitTarget( <0,0,0.75>, ZERO_ROTATION );


  		// if blank, we look in inventory

  		if (sitAnimation == "") {

  			sitAnimation = llGetInventoryName(INVENTORY_ANIMATION, 0);


  			// oops, use default

  			if (sitAnimation == "") {

  				sitAnimation = "sit";

  			}

  		}

  	}



  	// Using state to control sitting

  	// If you're in this state, no one is sitting

  	changed(integer change) {

  		if (change & CHANGED_LINK) {

  			key avatar = llAvatarOnSitTarget();

  			if ( avatar != NULL_KEY )  {

  				llRequestPermissions(avatar,PERMISSION_TRIGGER_ANIMATION);

  				 llSetTimerEvent(0.5) ; // keeps the tongue out permanently .. to keep on sticking your tongue in and out, change to something like 5.0

  			}

  		}		

  	}



  	run_time_permissions(integer parm) {

  		if(parm == PERMISSION_TRIGGER_ANIMATION) {

  			llStopAnimation("sit");

  			llStartAnimation(sitAnimation);

  			state sitting;

  		}

  	}	

  }



  state sitting {

  	state_entry() {

  	}




  	// Assume sitting, thus any CHANGED_LINK means standing.		

  	changed(integer change) {

  		if (change & CHANGED_LINK) {

  			llStopAnimation(sitAnimation);

  			llSetTimerEvent(0);

  			llResetScript();

  		}		

  	}

  timer()

  	{

  		restartAnimations() ;


  	}

  }