Syncing Parcel Media Script

[Evah Baxton]

You have to be the owner of the parcel.
You need to have Auto-play Media and Script Auto-play Media enabled for it to behave like in the video.
You can stop and start your media, leave the parcel, or logout and log back in and it will re-sync.  It will take 1 second to the amount of seconds you have set as the resync period (default 10 seconds).

This will override your media link and media texture settings on your parcel.

//Evah Baxton 2020

float timerCount=0;
integer videoLength=98; //video length in seconds
integer resync=10; //resync every 10 seconds
string mediaURL = "YOUR MEDIA HERE";
integer loop=1; //loop the synced video
integer displayTime=1; //display the seconds elapsed

default {

    state_entry() {
        llParcelMediaCommandList([
            PARCEL_MEDIA_COMMAND_STOP,
            PARCEL_MEDIA_COMMAND_URL,mediaURL,
            PARCEL_MEDIA_COMMAND_TEXTURE, (key) llGetTexture(0)
        ]);
    }

    touch_start(integer num_detected) {
        timerCount=0;
        llParcelMediaCommandList([
            PARCEL_MEDIA_COMMAND_STOP,
            PARCEL_MEDIA_COMMAND_URL,mediaURL,
            PARCEL_MEDIA_COMMAND_TEXTURE, (key) llGetTexture(0),
            PARCEL_MEDIA_COMMAND_TIME, timerCount,
            PARCEL_MEDIA_COMMAND_PLAY
        ]);
        llSetTimerEvent(0.15);
    }

    timer() {
        if(displayTime==1) {
            llSetText((string)timerCount, <1.0,0,0>,1.0);
        }
              
        if(llGetUnixTime()%resync==0) {
            timerCount=timerCount+resync;   
            llParcelMediaCommandList([
                PARCEL_MEDIA_COMMAND_TIME, timerCount
            ]);
        }
              
        if(timerCount >= videoLength) {
            timerCount=0;
            if(loop==0) {
                llSetTimerEvent(0.0);
            } else {
                llParcelMediaCommandList([
                    PARCEL_MEDIA_COMMAND_STOP,
                    PARCEL_MEDIA_COMMAND_PLAY
                ]);
            }
        }
              
    }
              
}

 

Edited January 31, 2020 by Evah Baxton

[Rolig Loon]

Nice work. Do you have a question about it?

[Evah Baxton]

I was just moving it out of the General Discussion Forum to make it available here. Is there a better place to post working scripts?

[Rolig Loon]

If you've tested it in world and it feels good, put it in the LSL Scripting Library. 

Edited January 31, 2020 by Rolig Loon

[Alyona Su]

2 hours ago, Evah Baxton said:

You have to be the owner of the parcel.
You need to have Auto-play Media and Script Auto-play Media enabled for it to behave like in the video.
You can stop and start your media, leave the parcel, or logout and log back in and it will re-sync.  It will take 1 second to the amount of seconds you have set as the resync period (default 10 seconds).

Just so I understand... this script is placed into the media prim (in your example: into the two televisions)?

[Evah Baxton]

34 minutes ago, Alyona Su said:

Just so I understand... this script is placed into the media prim (in your example: into the two televisions)?

Yes. The script sets the parcel's media texture to be the texture from face 0 of the object it is attached to.

[Evah Baxton]

It needs a good server and a relatively good internet connection. It works much better when the video is smaller.

The first time any user plays the media, it takes a moment to sync and buffer from the server. Sometimes it takes two or three syncs to get fully caught up.

This public test video has worked well for me:
http://commondatastorage.googleapis.com/gtv-videos-bucket/sample/WhatCarCanYouGetForAGrand.mp4