Jump to content

avatar scanning script help wanted


Sylvia Wasp
 Share

You are about to reply to a thread that has been inactive for 1696 days.

Please take a moment to consider if this thread is worth bumping.

Recommended Posts

Hello, 

I've been trying to write a script to scan for avatars in the area and turn the returned list into a set of dialogue buttons.  I've got part of the way there. I can invoke the dialogue, and I've figured out the scanner part, but when it comes to feeding that info back into the dialogue I'm lost and so far the wiki has been no real help.  

I know in some cases the dialogue part is handled by a separate script instead of being included in the main script.  Is that the way to go?

here is the code I have already:

// Sylvia's avatar scan code

integer cmdChannel;
list    visitor_list;
float   sensor_range = 96.0;


integer Key2Chan(key ID) 
{
    return 0x80000000 | (integer)("0x"+(string)ID);
}

integer isNameOnList( string name )
{
    integer len = llGetListLength( visitor_list );
    integer i;
    for( i = 0; i < len; i++ ){
        if( llList2String(visitor_list, i) == name ){
            return TRUE;
            }
        }
    return FALSE;
}
 
default
{
    state_entry()
    {
        cmdChannel = Key2Chan(llGetOwner());
        llListen(cmdChannel, "", llGetOwner(), "");
    }
                
    touch_start(integer total_number)
    {
        llDialog(llDetectedKey(0),"\n~VISITOR LIST~\n",
        ["find avatars","list","reset"],cmdChannel);
    }

    sensor( integer number_detected )
    {
        integer i;
        for( i = 0; i < number_detected; i++ ){
            if( llDetectedKey( i ) != llGetOwner() ){
                string detected_name = llDetectedName( i );
                if( isNameOnList( detected_name ) == FALSE ){
                    visitor_list += detected_name;
                    }
                }
            }    
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if( id != llGetOwner() ){
            return;
            }
        else if( message == "find avatars" ){
            llOwnerSay( "scanning for avatars within 96m ..." );
            llSensor("", NULL_KEY, AGENT, sensor_range, PI);
            }
        else if( message == "list" ){       
            llOwnerSay( "avatar List:" );
            integer len = llGetListLength( visitor_list );
            integer i;
            for( i = 0; i < len; i++ ){
                llOwnerSay( llList2String(visitor_list, i) );
                }
            llOwnerSay("Total = " + (string)len ); 
            }
        else if( message == "reset" ){
            visitor_list = llDeleteSubList(visitor_list, 0, llGetListLength(visitor_list));
            llOwnerSay("completed reset");
            }
    }        
}

 

Link to comment
Share on other sites

I don't think you'd need to split this into two scripts, you could use a function to work on the parsing and call it as needed. A great example of this can be seen in Rolig's dialog code in the script library:

Once your scanner has populated the list of names, call Rolig's function to build the dialog.

  • Like 1
Link to comment
Share on other sites

You're almost there.  You have packed the names into visitor_list, which is almost the list that you need to hand to llDialog as

llDialog(kAv, "\n Pick a name ... any name... ",  visitor_list, my_dialog_channel);

You need to do only a tiny bit more cleanup.  First, you need to truncate (or somehow reshape) the names to fit into 12-character dialog button labels.  Or you can put the names into a numbered list in the dialog message and then use numbered buttons >>> 

).. Second, you need to provide a dynamic way to remove names from visitor_list if the target avatars are no longer in sensor range.  Wiping the entire list clean with "Reset" is overkill.

Having done those things, you really can just drop your polished list directly into the llDialog statement.  Then you just have to figure out what to do when the script hears the response from a dialog button, but I'm sure you have plans for that.

 

Edit: Thank you, Fenix, for pointing to that script.  There are quite a few dialog/menu scripts in the Library that you can build on, or at least use for inspiration as you write your own.  I think most scripters have found that it's easiest to customize someone else's rough model to fit their own needs. 

Edited by Rolig Loon
  • Like 1
Link to comment
Share on other sites

8 hours ago, Rolig Loon said:

You're almost there.  You have packed the names into visitor_list, which is almost the list that you need to hand to llDialog as

llDialog(kAv, "\n Pick a name ... any name... ",  visitor_list, my_dialog_channel);

You need to do only a tiny bit more cleanup.  First, you need to truncate (or somehow reshape) the names to fit into 12-character dialog button labels.  Or you can put the names into a numbered list in the dialog message and then use numbered buttons >>> 

).. Second, you need to provide a dynamic way to remove names from visitor_list if the target avatars are no longer in sensor range.  Wiping the entire list clean with "Reset" is overkill.

Having done those things, you really can just drop your polished list directly into the llDialog statement.  Then you just have to figure out what to do when the script hears the response from a dialog button, but I'm sure you have plans for that.

 

Edit: Thank you, Fenix, for pointing to that script.  There are quite a few dialog/menu scripts in the Library that you can build on, or at least use for inspiration as you write your own.  I think most scripters have found that it's easiest to customize someone else's rough model to fit their own needs. 

Thanks Rolig, 

It will take me a while to ingest this stuff of course but the multi-page dialogue code will be especially useful indeed.  

I probably won't use the numbered buttons thing.  Scriptors won't understand this of course, but regular folks don't actually like numbers or numbered buttons. :)  Even the worst formatted, garbled name is better than numbers.  There is nothing worse than a dialogue on a piece of furniture that just has numbers for the poses for example.  

Currently the avatar list is a "scan once and done" kind of deal, I was intending to replace it with something that appends new names and removes names of avatars no longer detected.  I was going to stick with a manual "rescan" button however, rather than rely on a timer as it seemed more efficient. Most of the time you're only going to scan once anyway and constantly scanning around for avatars seems resource wasteful no matter how you do it. 

As for what to do with the names once compiled, each name will be a button so I was thinking that any response from the dialogue that *wasn't* an expected command would obviously be someone pressing a button with an avatars name on it.  So I would have an else-if at the end of the listen that executed the code on the avatars names.  

I will deal with all the avatar names as they are character-wise.  Those who have chosen ridiculous (and ridiculously long) avatar names will just be out of luck (for being ridiculous), and it will be their loss.  I'm a bit worried about escape characters, but I'm sure there is some way to deal with that. 

If I can identify a particularly useless sub-set of characters to screen out of the name strings I might do that, but with all the silly font nonsense that people do nowadays, it's unlikely that any particular character can be safely eliminated in that fashion.  Probably I will just take the first twelve characters and truncate the name.  

thanks again, :) 

Sylvia

 

  • Like 1
Link to comment
Share on other sites

That sounds good to me.  As a scripter, I tend to get fiddly about cleaning up loose ends and making my work as efficient as I can,  In the end, though, what always has to count first is that the script does what you want it to.  Just be sure that those names are all truncated so that they don't kick up a script error.  The odd high-bit ASCII characters won't look like anything readable, but if you can identify which avatar is which, that's enough.

Link to comment
Share on other sites

On 8/1/2019 at 9:18 PM, Rolig Loon said:

That sounds good to me.  As a scripter, I tend to get fiddly about cleaning up loose ends and making my work as efficient as I can,  In the end, though, what always has to count first is that the script does what you want it to.  Just be sure that those names are all truncated so that they don't kick up a script error.  The odd high-bit ASCII characters won't look like anything readable, but if you can identify which avatar is which, that's enough.

Well, I would also like it to be as efficient and "clean" as possible, but yes it's most important that it fit the situation it was made for.  

OK, so if anyone's still interested, here is a "version 2" of the thing.

- I've successfully dumped the list to "llDialog".  

- I've changed the sensor to read Display Names instead of the actual avatar names (no one seems to use those anymore) and truncated them at twelve characters. 

- I've made the sensor scan reset the list each time so it doesn't just get bigger and bigger with each scan, (which allowed me to remove the "reset" button).

- I've simplified the nomenclature a bit and chopped out as much unnecessary stuff as possible.

- I've added a bit to the end of the listen which would serve as an "action" for the avatar name buttons (currently it just says the name). 

I haven't dealt with the 12 button limit yet, because my intention is to (later on) dump the avatar_list to a multi-page dialog that expands to fit however long the list gets. I'm still working on understanding that part.  

I also need to add the "SCAN" button to the llDialog that lists the avatars names for better UI flow. 

What I don't understand is why I can't blend the "list" part with the "scan" part.  Every time I put the llDialog command after the scan, (within the same else-if as the scan), it reads as either empty or as just the first name in the list.  I seem to be forced to scan and list separately.  Other than that, and the fact that I'm still not checking for the button limit (and the fact that I'm probably not dealing with the listen handle as I should), it seems to work.  

// Sylvia's avatar scan code (take 2)

integer cmdChannel;
list    avatar_list;
float   sensor_range = 96.0;


integer Key2Chan(key ID) 
{
    return 0x80000000 | (integer)("0x"+(string)ID);
}
 
default
{
    state_entry()
    {
        cmdChannel = Key2Chan(llGetOwner());
        llListen(cmdChannel, "", llGetOwner(), "");
    }
                
    touch_start(integer total_number)
    {
        llDialog(llDetectedKey(0),"\n~AVATAR LIST~\n",
        ["SCAN","list"],cmdChannel);
    }

    sensor( integer number_detected )
    {
        avatar_list = llDeleteSubList(avatar_list, 0, llGetListLength(avatar_list));

        integer i;
        for( i = 0; i < number_detected; i++ ){
            if( llDetectedKey( i ) != llGetOwner() ){
                string detected_name = llGetDisplayName(llDetectedKey( i ));
                avatar_list += llGetSubString(detected_name, 0, 11);
                }
            }    
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if( id != llGetOwner() ){
            return;
            }
        else if( message == "SCAN" ){
            llOwnerSay( "scanning for avatars within 96m ..." );
            llSensor("", NULL_KEY, AGENT, sensor_range, PI);
            
            // why can't I put "llDialog" here?
            
            }
        else if( message == "list" ){
            llDialog(llGetOwner(), "\n avatars found ...",  avatar_list, cmdChannel);
            }
        else {
            llOwnerSay(message);
            }
    }        
}

 

Link to comment
Share on other sites

You can reset the avatar list more easily: avatar_list = [];.

You need to wait for the sensor to do its stuff and for your code to build the list of buttons before you display the dialog. It can go in at the end of the loop that builds the avatar list in the sensor event.

You could put the "SCAN" button text at the start of the avatar list so you can initiate a re-scan from the avatar list dialog. So when you reset the avatar list start it off like this: avatar_list = ["SCAN"];.

(First thing in the morning, and I've only just made my tea. I hope the effects aren't infecting my post.)

  • Like 2
Link to comment
Share on other sites

6 hours ago, KT Kingsley said:

You can reset the avatar list more easily: avatar_list = [];.

You need to wait for the sensor to do its stuff and for your code to build the list of buttons before you display the dialog. It can go in at the end of the loop that builds the avatar list in the sensor event.

You could put the "SCAN" button text at the start of the avatar list so you can initiate a re-scan from the avatar list dialog. So when you reset the avatar list start it off like this: avatar_list = ["SCAN"];.

(First thing in the morning, and I've only just made my tea. I hope the effects aren't infecting my post.)

thanks KT,  all great suggestions :) 

I feel like a dummy for not seeing that easier list reset.  So obvious once you see it, lol.  

I base most of my decisions on finding some example elsewhere, so lots of times it works, but is inappropriate to the setting or overly complicated.  

Sylvia

Link to comment
Share on other sites

Okay, so ... here is the code where I combined the multi-page button dialogue into what I already had as well as taking KT's simplification notes into account.  I renamed a lot of stuff and formatted it so it's clearer because I'm a super visual person (thus why I suck at code), and I simply can't even read it unless I do that.  

It (sorta) works?  

Obviously there is a problem with the touch_start event in that I'm calling my original dialogue box and then calling the multi-page dialogue box function right after.  If I comment out one or the other then it doesn't work at all, but the way it is currently, if I'm quick with hitting the SCAN button, then eventually it works fine and I get a multi-page dialogue with the correct forward and backward arrows and all the names of the avatars correctly formatted etc.  

So I'm 90% of the way there?  I mean it's working ... but with problems, lol. 

I'm thinking that what I want is a first page menu where I invoke the scan and then the multipage dialogue thingie is a *sub menu of that?  But I'm not sure how to do that either, lol. 

Anyway, here is what I have now for anyone still interested and thanks for all the help so far: 

 Sylvia

// Sylvia's avatar scan code (combined)
// 

integer cmdChannel;
integer gMenuPos;
integer gListen;

float   sensor_range = 96.0;
list    avatar_list;

integer Key2Chan(key ID) 
{
    return 0x80000000 | (integer)("0x"+(string)ID);
}

dialogue_box()
{
    integer lastPage;
    list    buttons;
    integer listLength = llGetListLength(avatar_list);
    
    if(gMenuPos >= 9) {
        buttons += "    <----";
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }    
    else if (listLength > gMenuPos+9) {
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }
    else {
        lastPage = TRUE;
        }

    if (listLength > 0) {
        integer b_count;
        integer num_of_buttons = llGetListLength(buttons);

        for(b_count = gMenuPos + num_of_buttons + lastPage - 1 ; (num_of_buttons < 12) && (b_count < listLength); ++b_count) {
            buttons = buttons + [llList2String(avatar_list,b_count)];
            num_of_buttons = llGetListLength(buttons);
            }
        }
    gListen = llListen(cmdChannel,"","","");    
    llSetTimerEvent(10.0);
    llDialog(llGetOwner()," \n",buttons,cmdChannel);
}

 
default
{
    state_entry()
    {
        cmdChannel = Key2Chan(llGetOwner());
        llListen(cmdChannel, "", llGetOwner(), "");
    }
                
    touch_start(integer total_number)
    {
        llDialog(llDetectedKey(0),"\n~AVATAR LIST~\n", ["SCAN"],cmdChannel);
        llListenRemove(gListen);
        gMenuPos = 0;
        dialogue_box();
    }

    sensor( integer number_detected )
    {
        avatar_list = ["SCAN"];
        integer i;
        for( i = 0; i < number_detected; i++ ){
            if( llDetectedKey( i ) != llGetOwner() ){
                string detected_name = llGetDisplayName(llDetectedKey( i ));
                avatar_list += llGetSubString(detected_name, 0, 11);
                }
            }
        llDialog(llGetOwner(), "\n avatars found ...",  avatar_list, cmdChannel);
    }
    
    listen( integer channel, string name, key id, string message )
    {
        llListenRemove(gListen);
        llSetTimerEvent(0.0);
        
        if( message == "SCAN" ){
            llOwnerSay( "scanning for avatars within 96m ..." );
            llSensor("", NULL_KEY, AGENT, sensor_range, PI);
            }
        else if (~llSubStringIndex(message,"---->")) {
            gMenuPos += 10;
            dialogue_box();
            }
        else if (~llSubStringIndex(message,"<----")) {
            gMenuPos -= 10;
            dialogue_box ();
            }
        else {
            llOwnerSay(message);
            }
    }        

    timer()
    {
        llSetTimerEvent(0.0);
        llListenRemove(gListen);
    }
}

 

Link to comment
Share on other sites

You may want to pay special attention to one of KT's suggestions (emphasis mine):

11 hours ago, KT Kingsley said:

You need to wait for the sensor to do its stuff and for your code to build the list of buttons before you display the dialog. It can go in at the end of the loop that builds the avatar list in the sensor event.

I don't want to wade into the middle here and risk confusing things, but eventually you'll probably want to do something in the case of no_sensor(). Not essential to your current objectives, though.

  • Like 2
Link to comment
Share on other sites

I've been out doing errands all day and have only had a few minutes to look at your current script, so I will probably miss something. KT and Qie are right, though.  Until the sensor has done its job, you don't have a current version of avatar_list to drop into a llDialog.  The place to call llDialog, therefore, is at the end of the sensor event. In fact, that's where you have put it in your latest post.  However, you are calling llDialog there instead of calling the dialogue_box routine that does all the multipage stuff.  The multipage dialog always starts with the the first (oldest) elements of avatar_list and then displays younger ones ten at a time on successive pages. That's what you should be calling. You can get rid of the llDialog statement at the start of the touch_start event as well, since you already call dialogue_box three lines later.

Link to comment
Share on other sites

15 hours ago, Rolig Loon said:

I've been out doing errands all day and have only had a few minutes to look at your current script, so I will probably miss something. KT and Qie are right, though.  Until the sensor has done its job, you don't have a current version of avatar_list to drop into a llDialog.  The place to call llDialog, therefore, is at the end of the sensor event. In fact, that's where you have put it in your latest post.  However, you are calling llDialog there instead of calling the dialogue_box routine that does all the multipage stuff.  The multipage dialog always starts with the the first (oldest) elements of avatar_list and then displays younger ones ten at a time on successive pages. That's what you should be calling. You can get rid of the llDialog statement at the start of the touch_start event as well, since you already call dialogue_box three lines later.

Thanks for chiming in Rolig, I realise that these questions must be both a bit on the easy/boring side, as well as one's you've been asked many times before.  In my searching for answers I found evidence of you helping out in the past on scripts very similar to mine (several times!). :) 

I realised my mistake about calling llDialog instead of the multipage routine right after I posted last time, so that's fixed already. 

The reason I am using llDIalog on the first touch, and then the multi-page routine later, is that I think what I want to do works best as a Menu/subMenu combination.  The first menu (llDialog) presents the user with an announcement of what's going to happen and presents the "SCAN" button ... then the results of the scan are (necessarily) dropped into the multipage menu system, which handles the data.  I'm not sure if it's correct, but that was the logic behind the choice.  

The trouble is that these two calls to Dialogue boxes are now fighting with each other.  

I press the "SCAN" button on the first dialogue box and it sometimes replaces with a blank box with an "OK" button for a moment, before then being replaced by the multipage dialogue box with the correct data.  Because the whole scanning and invoking of the multipage dialogue box takes a while, I made it work by putting in the llSLeep command, but then what is displayed is the last (old) data from the previous scan (in multipage format), before a moment later being replaced by the new, correct, scan data.  Either one creates a horrible user interaction and llSleep is definitely a kludge I don't want to use anyway.  

Sadly, I've also lost confidence that I even have the right approach for the task at hand. I realised that I probably need the avatars keys to do anything worthwhile with the named buttons at the end and I don't think you can find an avatars key with just the first 12 characters of their display names.  I can collect the keys instead, but then I need a whole other routine (in the listen?) to parse that data into display names before dumping them in the dialogue?  Or I need to collect two lists in the sensor (keys and names) and then associate them in a data structure with strided lists or something? Ack!   

The whole thing is a mess really, lol.

the relevant code section:

    touch_start(integer total_number)
    {
        llDialog(llDetectedKey(0),"\n~Press SCAN for a list of avatars~\n", ["SCAN"],cmdChannel);
        llListenRemove(gListen);
        gMenuPos = 0;
    }

    sensor( integer number_detected )
    {
        avatar_list = ["SCAN"];
        integer i;
        for( i = 0; i < number_detected; i++ ){
            if( llDetectedKey( i ) != llGetOwner() ){
                string detected_name = llGetDisplayName(llDetectedKey( i ));
                avatar_list += llGetSubString(detected_name, 0, 11); 
                }
            }
        llSleep(2.0);
        multipage_dialogue();
    }

 

Link to comment
Share on other sites

1 hour ago, Sylvia Wasp said:

The reason I am using llDIalog on the first touch, and then the multi-page routine later, is that I think what I want to do works best as a Menu/subMenu combination.  The first menu (llDialog) presents the user with an announcement of what's going to happen and presents the "SCAN" button ... then the results of the scan are (necessarily) dropped into the multipage menu system, which handles the data.  I'm not sure if it's correct, but that was the logic behind the choice.  

I understand what you are trying to do, but I think you've made things unnecessarily complicated.  Right now, you have 

       avatar_list = ["SCAN"];

at the top of the sensor event, so that it's the first thing loaded into avatar_list.  My own choice would be to put that line at the top of the touch_start event and then say 

     dialogue_box();

instead of 

       llDialog(llDetectedKey(0),"\n~Press SCAN for a list of avatars~\n", ["SCAN"],cmdChannel);

The point is that the dialog_box routine will always give you the first page of a multipage dialog.  If avatar_list contains only ["SCAN"], then that's all that will appear in the dialog.  No subsequent pages.  That's exactly what you want.

Stepping back from the immediate question to address a philosophical point ...  When I write a script (except for a dirt simple one that I can write with my eyes closed), I have a running dialog in my head, explaining what I am doing in words that my rather intelligent by non-scripting grandmother could have understood.  I figure that if Granny can understand what I am saying, then I must have a pretty clear idea of how the script is going to work in world.  My point is the not-too-subtle one that computers will only do what you tell them, whether you meant it or not.  Scripting is 90% logic.  It does not allow for ambiguities.  Your task is to write directions that are clear as a bell, do not leave ambiguous or unfulfilled pathways, and try to anticipate the ways that an end user might try to make the script do something that you didn't intend.  I have always figured that I have lived up to the task if I can explain my logic clearly enough to satisfy my grandmother.  That's why she is in my head.

Link to comment
Share on other sites

On 8/4/2019 at 10:28 AM, Rolig Loon said:

...

Stepping back from the immediate question to address a philosophical point ...  When I write a script (except for a dirt simple one that I can write with my eyes closed), I have a running dialog in my head, explaining what I am doing in words that my rather intelligent by non-scripting grandmother could have understood.  I figure that if Granny can understand what I am saying, then I must have a pretty clear idea of how the script is going to work in world.  My point is the not-too-subtle one that computers will only do what you tell them, whether you meant it or not.  Scripting is 90% logic.  It does not allow for ambiguities.  Your task is to write directions that are clear as a bell, do not leave ambiguous or unfulfilled pathways, and try to anticipate the ways that an end user might try to make the script do something that you didn't intend.  I have always figured that I have lived up to the task if I can explain my logic clearly enough to satisfy my grandmother.  That's why she is in my head.

Very interesting.  A part of the reason I hate code is that I find it difficult to get that clear conception in my head.  When I'm painting a picture, or making something out of prims, or using a design/paint program I *begin* with a definite, clear, "vision" if you will of exactly what it looks like when it's finished then I just keep working until the reality matches the vision.  With code on the other hand I usually feel like I'm crawling across a bumpy floor in complete darkness looking for "stuff" and only about half-way through (if I'm lucky) do I get a clear vision of what it is I should be doing or working towards.  

In any case, due to the help that I've received here, I've managed to correct all the stupid errors (I think) and had a long talk with Grandmother about what it is I'm doing.  

She said ... that what I want in the end is avatar keys, and what I want for the dialogue box is avatar names and I want them associated together.  So what I really want is a database.  The closest thing to a database in SL is the strided list, so I spent a day reading up on strided lists and re-wrote the thing from that perspective and with (most) stupid errors removed. 

It's not that different but at least it finally works OK and could be said to be "finished" in terms of my original question at the top of the thread.  It scans the area for avatars, produces a nice button list of their names, and clicking on a button gives you their name and their key so you can "do stuff" with it.  

There are some things I'd like to make it work better though.  

1) I had no idea that sensor was limited to 16 avatars!  Is there any way around that at all?

2) It sometimes errors out saying that I have a button with more than 24 characters (when obviously I don't).  So far this has only happened in a Linden Hub where the crowd is mostly griefers, racists, paedophiles, & Trump supporters, so I'm thinking it's either LAG or shenanigans of some kind.  

2b) if it's LAG, is there any way to assure that bits of the script don't execute in the wrong order or that every part of it waits properly before continuing in a high lag environment?  

2c) if it's shenanigans, that suggests that a player can "do something" to their display name to screw up my code. Is that really possible? 

Edit: Just realised that the avatar_list = ["SCAN"];  at the beginning of the sensor is probably unnecessary or should be blank.

// ====== Sylvia's Avatar Detect v2 ======

integer cmdChannel;
integer gMenuPos;
integer gListen;

float   sensor_range = 96.0;
list    detected_list;
list    avatar_list;

integer Key2Chan(key ID) 
{
    return 0x80000000 | (integer)("0x"+(string)ID);
}

multipage_dialogue()
{
    integer lastPage;
    list    buttons;
    integer listLength = llGetListLength(avatar_list);
    
    if(gMenuPos >= 9) {
        buttons += "    <----";
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }    
    else if (listLength > gMenuPos+9) {
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }
    else {
        lastPage = TRUE;
        }

    if (listLength > 0) {
        integer b_count;
        integer num_of_buttons = llGetListLength(buttons);

        for(b_count = gMenuPos + num_of_buttons + lastPage - 1 ; (num_of_buttons < 12) && (b_count < listLength); ++b_count) {
            buttons = buttons + [llList2String(avatar_list,b_count)];
            num_of_buttons = llGetListLength(buttons);
            }
        }
    gListen = llListen(cmdChannel,"","","");    
    llSetTimerEvent(10.0);
    llDialog(llGetOwner()," \n",buttons,cmdChannel);
}

 
default
{
    state_entry()
    {
        cmdChannel = Key2Chan(llGetOwner());
        llListen(cmdChannel, "", llGetOwner(), "");
    }
                
    touch_start(integer total_number)
    {
        avatar_list = ["SCAN"];
        multipage_dialogue();
        llListenRemove(gListen);
        gMenuPos = 0;
    }

    sensor( integer number_detected )
    {
        avatar_list = ["SCAN"];
        detected_list = [];
        integer i;
        for( i = 0; i < number_detected; i++ ){
            if( llDetectedKey( i ) != llGetOwner() ){
                string detected_name = llGetSubString(llGetDisplayName(llDetectedKey( i )), 0, 11);
                key detected_key = llDetectedKey( i);
                detected_list += detected_name;
                detected_list += detected_key;
                }
            }
        avatar_list = llList2ListStrided(detected_list, 0, -1, 2);
        multipage_dialogue();
    }
    
    listen( integer channel, string name, key id, string message )
    {
        llListenRemove(gListen);
        llSetTimerEvent(0.0);
        
        if( message == "SCAN" ){
            llOwnerSay( "scanning for avatars within 96m ..." );
            llSensor("", NULL_KEY, AGENT, sensor_range, PI);
            }
        else if (~llSubStringIndex(message,"---->")) {
            gMenuPos += 10;
            multipage_dialogue();
            }
        else if (~llSubStringIndex(message,"<----")) {
            gMenuPos -= 10;
            multipage_dialogue ();
            }
        else {
            llOwnerSay(message);
            llOwnerSay((string) llList2String(detected_list, (llListFindList(detected_list,[message]) + 1))); 
            multipage_dialogue ();
            }
    }        

    timer()
    {
        llSetTimerEvent(0.0);
        llListenRemove(gListen);
    }
}

 

Edited by Sylvia Wasp
Link to comment
Share on other sites

25 minutes ago, Sylvia Wasp said:

She said ... that what I want in the end is avatar keys, and what I want for the dialogue box is avatar names and I want them associated together.  So what I really want is a database.  The closest thing to a database in SL is the strided list, so I spent a day reading up on strided lists and re-wrote the thing from that perspective and with (most) stupid errors removed. 

Congratulations.  She was right.  Strided lists are a good solution.  Personally, I prefer to work with parallel, unstrided lists that accomplish the same thing, but scripters all do whatever they feel most comfortable with.  In the end, the goal is to create scripts that do what they are supposed to.

25 minutes ago, Sylvia Wasp said:

I had no idea that sensor was limited to 16 avatars!  Is there any way around that at all?

Yes, there is.  In fact, there are several ways around it.  The easiest is to abandon llSensor altogether and use llGetAgentList, which will give you a list of keys for every blessed avatar in the region (or parcel).  You use it, typically, by calling the function in a touch_start event or (if you really want something like a repeating sensor) in a timer event.  You have to go through a bit of juggling to create a parallel list of avatar names from those keys, but from there on, you use the results the same way that you are using sensor results now.

25 minutes ago, Sylvia Wasp said:

It sometimes errors out saying that I have a button with more than 24 characters (when obviously I don't).  So far this has only happened in a Linden Hub where the crowd is mostly griefers, racists, paedophiles, & Trump supporters, so I'm thinking it's either LAG or shenanigans of some kind.

I think it's unlikely to be due to lag or shenanigans. Chances are good that someone in that unruly crowd has a display name with unprintable characters, adding to the visible ones and pushing the length over the limit.  You might try using llStringTrim in addition to the truncation scheme you have now, to see if it makes a difference. 

In the end, of course, it doesn't truly matter which name shows up on your dialog buttons, because you are the only one who will see them anyway.  As long as they are recognizable, your system will do what you intended.  I know that you have expressed a dislike for numbered buttons, but that's exactly what was going through my mind as I wrote the script that I pointed out for you.  The names that your script collects all show up in the text portion of the dialog box, where they do not have to be truncated at all.  Each name has a number next to it, and it's the number that appears on the dialog button.

Edited by Rolig Loon
typos. as always.
  • Like 1
Link to comment
Share on other sites

1 hour ago, Rolig Loon said:

Congratulations.  She was right.  Strided lists are a good solution.  Personally, I prefer to work with parallel, unstrided lists that accomplish the same thing, but scripters all do whatever they feel most comfortable with.  In the end, the goal is to create scripts that do what they are supposed to.

Yes, there is.  In fact, there are several ways around it.  The easiest is to abandon llSensor altogether and use llGetAgentList, which will give you a list of keys for every blessed avatar in the region (or parcel).  You use it, typically, by calling the function in a touch_start event or (if you really want something like a repeating sensor) in a timer event.  You have to go through a bit of juggling to create a parallel list of avatar names from those keys, but from there on, you use the results the same way that you are using sensor results now.

I think it's unlikely to be due to lag or shenanigans. Chances are good that someone in that unruly crowd has a display name with unprintable characters, adding to the visible ones and pushing the length over the limit.  You might try using llStringTrim in addition to the truncation scheme you have now, to see if it makes a difference. 

In the end, of course, it doesn't truly matter which name shows up on your dialog buttons, because you are the only one who will see them anyway.  As long as they are recognizable, your system will do what you intended.  I know that you have expressed a dislike for numbered buttons, but that's exactly what was going through my mind as I wrote the script that I pointed out for you.  The names that your script collects all show up in the text portion of the dialog box, where they do not have to be truncated at all.  Each name has a number next to it, and it's the number that appears on the dialog button.

Cool. 

I wish there were another way around the 16 avatar limit than getting a list of every avatar in a sim though which may be very long and unwieldy for my purposes, but it’s something I’ll have to try.  

The original idea was for a HUD that would be used in a busy store or a dance floor situation. Basically scanning the avatars around you, that you can see.  Collecting the whole sim means collecting avatars in other contexts doing other things that the user can neither see nor in many cases is even aware of, which may be confusing for them besides being a possible invasion of privacy.  

Only collecting 16 avatars seems far too few and trying to collect the whole sim seems like overkill.  30 or so would be perfect, but if those are the only choices then I will have to pick one or the other.  Perhaps I can collect the whole sim, then sort by distance and mask out those avatars clearly out of range of the present location/context of the user.  It will be interesting to try.  

might also try the numbered buttons thing after all as it (foolishly) didn’t occur to to me that there would be a text based ‘key’ to the numbered buttons as you describe above.  My frustration with numbered buttons was more because blank numbered buttons don’t convey anything to the user, as in my example of a piece of furniture that just presents the user with buttons labelled 1-12 for poses.  

Thanks again for all the help. :) 

Sylvia

Link to comment
Share on other sites

8 minutes ago, Sylvia Wasp said:

Perhaps I can collect the whole sim, then sort by distance and mask out those avatars clearly out of range of the present location/context of the user.  It will be interesting to try.  

llGetAgentList with parameter AGENT_LIST_PARCEL is usually where we start this.  Then as you say filter the list for agents within a range

there is example wiki code showing how this can be done

http://wiki.secondlife.com/wiki/LlGetAgentList

  • Like 2
Link to comment
Share on other sites

8 minutes ago, Sylvia Wasp said:

Perhaps I can collect the whole sim, then sort by distance and mask out those avatars clearly out of range of the present location/context of the user.  It will be interesting to try.  

That's exactly the way to do it.  As you look in the LSL wiki, you'll see that llGetAgentList allows you to collect keys across the entire region or across the parcel that you happen to be in at the moment.  In either case, you can always filter the results further by ruling out avatars that are too far away, not in your group, too tall, or whatever.

In the years before that function was introduced, scripters invented several other clever solutions, most of which are clumsy by comparison.  Some, however, offer suggestions for ways to scan for things other than avatars.  My favorites are devices that behave like drones, flitting around the region and making sensor scans in overlapping areas.  If you search through earlier incarnations of these forums, you'll find some of Void Singer's scanners that work that way.

  • Like 1
Link to comment
Share on other sites

2 hours ago, Rolig Loon said:

That's exactly the way to do it.  As you look in the LSL wiki, you'll see that llGetAgentList allows you to collect keys across the entire region or across the parcel that you happen to be in at the moment.  In either case, you can always filter the results further by ruling out avatars that are too far away, not in your group, too tall, or whatever.

In the years before that function was introduced, scripters invented several other clever solutions, most of which are clumsy by comparison.  Some, however, offer suggestions for ways to scan for things other than avatars.  My favorites are devices that behave like drones, flitting around the region and making sensor scans in overlapping areas.  If you search through earlier incarnations of these forums, you'll find some of Void Singer's scanners that work that way.

A lot of the earlier work (even though I don't understand it) seemed much more creative to me.  I was once given a machine by Xylor Baysklef, made out of prims itself, that used scripts to rez rods and balls and panels that then self assembled into giant geodesic spheres in the air.  It was a beautiful, elegant and intuitive design and a wonder just to watch it do it's work.  It was made long before mesh and most of the scripting possibilities that exist today. 

Link to comment
Share on other sites

I don't think it's quite fair to say that creators were any more creative then than they are now, but we did have to come up with some very tricky workarounds to do things that are a lot easier now.  Even something as simple as a door was a lot harder to script before we had SLPPF and the PRIM_POS_LOCAL and PRIM_ROT_LOCAL options, for example.  Some of those old kludges were great fun but really klunky.  The standard has risen since those days, in part because we have more sophisticated tools to work with, so scripters and designers are tackling some problems that we wouldn't have dreamed of years ago. 

Link to comment
Share on other sites

Okay, I honestly thought this thread was over, lol ... but I can't seem to put this thing down.

So, I quickly rewrote the script using llGetAgentList and it works but I'd like some feedback because my solution feels a bit "messy" to me.  I have some stuff in the touch event that may not really belong there?  May not be necessary even?  

I didn't end up restricting it by distance as during my testing it was fast and smooth and the number of avatars doesn't seem to affect things at all (I imagine this is because it's a single call to the server for a list instead of a cumbersome scan/calculation?) not sure. 

What it's missing is:

- a "re-scan" button (every time I add extra buttons beyond the avatar list into the mix, things seem to screw up)

- a timer to disappear the dialogue box if nothing it touched for a while (or a reset button?)

Anyway, here it is.  Detects all avatars in a sim, creates a strided list (distance, display name, key) and sorts by distance.  Presents the user with a multi-page dialogue filled with buttons with the avatars names on them.  Pressing one of the named buttons gives you the name and key of that avatar (so you can do stuff).  I also (I think) added in the handler for "no avatars found" (re: Qie's comment on the earlier script).

It all seems to work, but please ... tell me what's wrong with it.  :) 

// ====== Sylvia's Avatar Detect v3 ======

integer cmdChannel;
integer gMenuPos;
integer gListen;

list    detected_list;
list    avatar_list;

integer Key2Chan(key ID) 
{
    return 0x80000000 | (integer)("0x"+(string)ID);
}

multipage_dialogue()
{
    integer lastPage;
    list    buttons;
    integer listLength = llGetListLength(avatar_list);
    
    if(gMenuPos >= 9) {
        buttons += "    <----";
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }    
    else if (listLength > gMenuPos+9) {
            if((listLength - gMenuPos) > 11) {
                buttons += "    ---->";
                }
            else {
                lastPage = TRUE;
                }            
        }
    else {
        lastPage = TRUE;
        }

    if (listLength > 0) {
        integer b_count;
        integer num_of_buttons = llGetListLength(buttons);

        for(b_count = gMenuPos + num_of_buttons + lastPage - 1 ; (num_of_buttons < 12) && (b_count < listLength); ++b_count) {
            buttons = buttons + [llList2String(avatar_list,b_count)];
            num_of_buttons = llGetListLength(buttons);
            }
        }
    gListen = llListen(cmdChannel,"","","");    
    llSetTimerEvent(10.0);
    llDialog(llGetOwner()," \n",buttons,cmdChannel);
}

 
default
{
    state_entry()
    {
        cmdChannel = Key2Chan(llGetOwner());
        llListen(cmdChannel, "", llGetOwner(), "");
    }
                
    touch_start(integer total_number)
    {
        llListenRemove(gListen);
        llSetTimerEvent(0.0);
        gMenuPos = 0;
        avatar_list = ["SCAN"];
        multipage_dialogue();
    }
    
    listen( integer channel, string name, key id, string message )
    {                
        if( message == "SCAN" ){
            avatar_list = [];
            llOwnerSay( "scanning for avatars within 96m ..." );
            
            key     thisKey;
            vector  currentPos = llGetPos();
            list    keys = llGetAgentList(AGENT_LIST_REGION, []);
            integer number_of_keys = llGetListLength(keys);
     
            integer i;
            for (i = 0; i < number_of_keys; ++i) {
                thisKey = llList2Key(keys,i);
                if (thisKey != llGetOwner()) {
                    detected_list += [
                        llRound(llVecDist(currentPos, llList2Vector(llGetObjectDetails(thisKey,[OBJECT_POS]),0))), 
                        llGetSubString(llGetDisplayName(thisKey), 0, 11),
                        thisKey 
                        ];
                    }
                }
            detected_list = llListSort(detected_list, 3, FALSE);
            avatar_list = llList2ListStrided(llDeleteSubList(detected_list, 0, 0), 0, -1, 3);
                if (llGetListLength(avatar_list) < 1) {
                    return;
                    // probably needs to give a message about "no avatars found" here
                    }
                else
                    multipage_dialogue();
            }
        else if (~llSubStringIndex(message,"---->")) {
            gMenuPos += 10;
            multipage_dialogue();
            }
        else if (~llSubStringIndex(message,"<----")) {
            gMenuPos -= 10;
            multipage_dialogue ();
            }
        else {
            llOwnerSay(message);    // the (named) button you pressed
            llOwnerSay((string) llList2String(detected_list, (llListFindList(detected_list,[message]) + 1)));   // the key!
            multipage_dialogue ();
            }
    }        

    timer()
    {
        llSetTimerEvent(0.0);
        llListenRemove(gListen);
    }
}

 

Edited by Sylvia Wasp
Link to comment
Share on other sites

25 minutes ago, Sylvia Wasp said:

What it's missing is:

- a "re-scan" button (every time I add extra buttons beyond the avatar list into the mix, things seem to screw up)

I'm not sure exactly sure what you mean by "add extra buttons."  Each time you click to trigger the touch_start event, you are clearing avatar_list.  Anyone detected in the next scan is being "added" to an empty list.  Now, I do notice in passing that you have not been emptying the detected_list as well, so you are adding information there.  That's almost certainly a mistake, but I don't have time at the moment to think through your logic and see just where it will cause problems first.

25 minutes ago, Sylvia Wasp said:

What it's missing is:

- a timer to disappear the dialogue box if nothing it touched for a while (or a reset button?)

Ah, well .... don't we all wish we could do that?  The best you can do is either (a) be sure that the dialog is disabled by using a timer and llListenRemove or (b) replace it with another useless dialog that has nothing but an "OK" button and a message to "Click here to get rid of this stupid dialog box."  Actually, my own solution is often to add a "DONE" button to the menu.  People seem drawn by the word "DONE".  They click it to get closure, a sense of finality.  "DONE" doesn't have to do anything except close the listen handler, but it incidentally also gets rid of the dialog box.  The only catch, of course, is that some people are not as compulsive about getting things "DONE" as others are, so that bit of psychological design doesn't always work on everyone.

EDIT:  I can't resist...   Welcome to the world of scripting. No script is ever finished.....

25 minutes ago, Sylvia Wasp said:

Okay, I honestly thought this thread was over, lol ... but I can't seem to put this thing down.

Edited by Rolig Loon
Link to comment
Share on other sites

4 hours ago, Rolig Loon said:

I'm not sure exactly sure what you mean by "add extra buttons."  Each time you click to trigger the touch_start event, you are clearing avatar_list.  Anyone detected in the next scan is being "added" to an empty list. 

Well, the "SCAN" button is always presented in the first dialogue box from the touch event, but previously the structure has been that the avatar list is appended to that, so that even when the buttons are populated with names, one of them is always "SCAN."  This gives the user the option of (re)SCAN-ing to refresh the list.  

While this was easy at first, now that I'm using strided lists and a bunch of (to me) super-complicated and counter-intuitive functions to grab/slice/sort various parts of said strided list, the addition of non-strided data just made things super confusing so I left it out of this version.  In this version, after the initial SCAN button is presented and clicked, it's replaced by the avatar name buttons.  

I would like to include it again, and possibly a "Done" and a "Reset" mostly for the same reasons you mention yourself about user interactions.  I'll probably figure out a way to do it eventually.  I think I need to read up on ordering/formatting the button layout but that's also super-confusing too, so I guess I've been avoiding dealing with it.  

4 hours ago, Rolig Loon said:

Now, I do notice in passing that you have not been emptying the detected_list as well, so you are adding information there.  That's almost certainly a mistake, but I don't have time at the moment to think through your logic and see just where it will cause problems first.

This is funny because the very last thing I did before I posted this code was to remove a detected_list = [ ]; from the code at the top of the SCAN section of the listen because it was stopping the whole script from working.  It made detected_list unavailable to the last part of the listen where I use it to get the avatar key, which is the whole point of the script.    

The avatar_list = ["SCAN"]; in the touch event functions (sort of) as a clearing of that list in that it replaces whatever might have been in there before.  Should I also have detected_list = [ ]; there for the same reason?  As I said, if I put it in the listen, where avatar_list = [ ]; is, it breaks the whole script.  

And since both lists are declared at the top ... why should I need to put it in the touch event anyway?  Is putting avatar_list = ["SCAN"]; and detected_list = [ ]; at the top with the other variables the same thing as putting it in the touch event?  Do I have to do both?  Is one better than the other? 

In short, I'm still confused as to where exactly to put things, or whether I've put them in the right place, since LSL doesn't seem to check for duplicate variable names or anything to do with context.  I call detected_list at the top, but if I call it again within a loop of a listen, then it's treated like a completely different, second list but with the same name?? WTF? And the compiler produces no errors to inform you of your mistake??  Insanity! (lol) :)  

Where to call things, and which parts of the script those things will ultimately be available too, or "seen by," has to be the most confusing and screwed up part of the whole LSL scripting language.  I'm not super experienced as I noted, but it seems highly irregular to me relative to other scripting languages I've used.

I don't really expect you to answer these questions.  I'm just trying to convey how confusing and nonsensical all this is to the novice scripter. :( 

ok </rant> over, lol

Sylvia 

Edited by Sylvia Wasp
  • Like 1
Link to comment
Share on other sites

13 hours ago, Sylvia Wasp said:

While this was easy at first, now that I'm using strided lists and a bunch of (to me) super-complicated and counter-intuitive functions to grab/slice/sort various parts of said strided list, the addition of non-strided data just made things super confusing so I left it out of this version.  In this version, after the initial SCAN button is presented and clicked, it's replaced by the avatar name buttons.  

That sounds like good reasoning.  I am not much of a fan of strided lists myself, although they are as close as we get to having arrays in LSL. I prefer to work with unstrided lists, even though it means keeping track of list indices all the time.  (Actually, I guess that's the reason I prefer them. They force me to deal explicitly with the size and order of elements in every blessed list and to watch carefully as I add and remove elements, to be sure that lists remain in sync.)  The functions for doing all of that with strided lists seem more complicated than they really need to be.  In this case, you are dealing with a strided list (which you sort) and an unstrided list.  You're doing a masterful job of juggling them,  but it is a lot of work.  I guess it would be, no matter what approach you take, but it's no surprise that they are giving you headaches.

13 hours ago, Sylvia Wasp said:

The avatar_list = ["SCAN"]; in the touch event functions (sort of) as a clearing of that list in that it replaces whatever might have been in there before.  Should I also have detected_list = [ ]; there for the same reason?  As I said, if I put it in the listen, where avatar_list = [ ]; is, it breaks the whole script.  

And since both lists are declared at the top ... why should I need to put it in the touch event anyway?  Is putting avatar_list = ["SCAN"]; and detected_list = [ ]; at the top with the other variables the same thing as putting it in the touch event?  Do I have to do both?  Is one better than the other? 

You have only declared those two global lists once each ... at the top of the script.  After that, you are adding or removing elements.  For your purposes, clearing both lists when you click to trigger the touch_start event gives you a clean slate to work with.  You don't want the script to remember anything about a previous scan.  It truly doesn't matter whether you clear the lists in the touch_start event or the listen event, as long as they are cleared before you start manipulating them.

Writing a script like this is great fun.  It's a challenge in logic.  Personally, I find it hard to avoid two temptations: (1) anticipating the behavior of the script entirely in my own head and (2) tinkering with too many things at once.  I tend to wait far too long before peppering a script with diagnostic llSay statements to find out what is really going on at key points and then I try to fix several things at the same time. It's an odd mix of overconfidence and impatience on my part, and it's deadly when I get lost in the weeds, chasing mismatched lists through nested if tests.  I rely too heavily on intuition to help me leap over problems.  It's not a good strategy and I do not recommend it. Instead, ask the script what it's doing, and be patient.

  • Like 2
Link to comment
Share on other sites

You are about to reply to a thread that has been inactive for 1696 days.

Please take a moment to consider if this thread is worth bumping.

Please sign in to comment

You will be able to leave a comment after signing in



Sign In Now
 Share

×
×
  • Create New...