Solved: Stuck on llSensorRepeat

[WendyTalia]

key AvKey; 
startsensor()
    {
    llSensorRepeat("", AvKey, AGENT, 20.0, PI, 10.0);
    llSetTimerEvent(90);
    }
default
{   
    touch_start(integer total_number)
    {
        AvKey = llDetectedKey(0); startsensor();
    }
    sensor(integer num_det)
    {    
        integer i;        for(i = 0; i < num_det; i++)       
        {  
               if (AvKey == llDetectedKey(i))
                    {
                        llSay(0, llGetUsername(AvKey) + " Detected");
                    }
               else {llShout(0, "Not Detected");   //this bit not working 
                    } 
        }
    }
    timer()
    {   
        llSensorRepeat("", AvKey, AGENT, 10.0, PI, 0.0);
    }    
}

 

I can't get the "else" bit to work for some reason. It's for a game where I don't want people cheating by going close to the object. It's just as important to know when they aren't in range.

Edited October 18, 2018 by WendyTalia
solved

[Wulfie Reanimator]

The sensor event will ONLY happen if an avatar is detected. The no_sensor event will happen if no avatar is in range. 

Edit: Never mind, I skimmed too fast.

Edit 2: Never mind, I think what I said still applies.

If the object is touched but NO ONE is near it, the sensor event won't trigger and you can't get it to shout. Your code works as long as someone else is near the object, but you will also need a no_sensor event with the same code as in the "else" condition.

Edited October 18, 2018 by Wulfie Reanimator

[WendyTalia]

Oh thank you! Makes sense now. No_sensor works.

[Wulfie Reanimator]

Just now, WendyTalia said:

Oh thank you! Makes sense now. No_sensor works.

I just edited my post because I was too quick to correct myself. You will need to do both.

[Shymus Roffo]

A very good example of the no_sensor event can be found on the wiki.

http://wiki.secondlife.com/wiki/No_sensor

I'm assuming you're trying to see if the person who touched the prim is within 20m of the prim. Another way you could go about this like the example below. This may remove your use for the sensor. (Unless you want it, then don't do this.)

key avKey;
float distance = 20;

integer InRange(key uuid, float distance) {
    list data = llGetObjectDetails(uuid, [OBJECT_POS]);
    if(data == [])
        return 0;
    return llVecDist(llList2Vector(data, 0), llGetPos()) <= distance;
}

default {
    touch_start(integer n) {
        avKey = llDetectedKey(0);
        if(InRange(avKey, distance)) {
            llOwnerSay("Within Range");
        } else {
            llOwnerSay("Not within range");
        }
    }
}

 

[Innula Zenovka]

Or, alternatively

float fMaxDist = 20.0;
default
{
	state_entry()
	{

	}
	touch_start(integer total_number)
	{
		if(llVecDist(llGetPos(),llDetectedPos(0))<=fMaxDist){
			//go ahead and process the touch
		}
		else{
			llRegionSayTo(llDetectedKey(0),0,"Come closer.  You are too far away to touch the target");
		}

	}
}

 

[Rolig Loon]

As Innula and Shymus pointed out, there's no reason to need a sensor in this script.  That's just extra work. Your touch_start event automatically gives you llDetectedPos() information already if you ask for it.

BTW, For your own peace of mind in later scripts, and for anyone else who might be reading your scripts, I suggest never putting more than one statement on the same line of code.  When you're debugging code, it's easy to overlook an important instruction in lines like

2 hours ago, WendyTalia said:

    integer i;        for(i = 0; i < num_det; i++)

and

2 hours ago, WendyTalia said:

    AvKey = llDetectedKey(0); startsensor();

?

[WendyTalia]

Thank you for your replies! That was a cleaned up version for the forum. Ha! I do need to work on formatting them.

The sensor is for an archery target so the on touch is just when you start the game. Then it needs to know if you stay at a reasonable distance. It's only for a short time then turns off when the game is finished so I figured that wouldn't be so bad. I added an owner option to turn the sensor off explaining it's not great for laggy sims. Do you think? 

Those scripts you posted are great ideas that could come in handy for other projects.Very simple. I love those adventure games with experiences where range on touch is essential. I have a few ides in mind.