Reset Multiple Scripts in Primset

[EnCore Mayne]

i have a primset HUD that i'd like to be able to reset all the scripts on touch of a button on the HUD. any hints?

i've tried an llResetScript() but as soon as it fires, the root's script resets but all the others are left unreset.

if i understand llResetOtherScript() properly, that only resets scripts in the root. these other scripts are spread out throughout the primset.

[Rachel1206]

Use llMessageLinked to send a command to your child prims and execute llResetScript.

Now IF the prim should hold more than one script, your can solve it by doing as below:

resetOtherScripts()
{
    string strName;
    integer l = llGetInventoryNumber( INVENTORY_SCRIPT );
    integer i;
    for( i = 0; i < l; i++ )
    {
        strName= llGetInventoryName( INVENTORY_SCRIPT, i );
        if(  strName!= llGetScriptName() ){
            llResetOtherScript( strName );
        }
    }
}

[Rolig Loon]

I use the method that Rachel described all the time.  In objects that contain many scripts, it may be wise to restart them one at a time instead of doing them all together.  In that case, just build the restarts into a timer:

integer giCount;
integer giNumScripts;

default
{
    link_message(integer from, integer iCode, string message, key id)
    {
        if (message == "RESTART")
        {
            giNumScripts = llGetInventoryNumber(INVENTORY_SCRIPT);
            giCount = 0;
            llSetTimerEvent(0.2);
        }
    }
    timer()
    {
        if (giCount < giNumScripts)
        {
            if (llGetInventoryName(INVENTORY_SCRIPT,giCount) != llGetScriptName())
            {
                llResetOtherScript(llGetInventoryName(INVENTORY_SCRIPT,giCount));
            }
            ++giCount;
        }
        else
        {
            llSetTimerEvent(0.0);
        }
    }
}

   

[EnCore Mayne]

llMessageLinked() was just what i needed to learn. works perfectly well (within LL standards of perfection, haha).